From 63904ea09f75249760b45fea6bdd349feb2fb2d3 Mon Sep 17 00:00:00 2001
From: Bryan McShea <cat71602@gmail.com>
Date: Tue, 11 Oct 2022 17:54:20 -0400
Subject: [PATCH] initial commit

---
 Makefile         |   9 ++
 build/main       | Bin 0 -> 9624 bytes
 build/test.txt   | Bin 0 -> 14 bytes
 run              |  13 +++
 src/lib/format.s |  62 +++++++++++++
 src/lib/heap.s   | 225 +++++++++++++++++++++++++++++++++++++++++++++++
 src/lib/print.s  |  95 ++++++++++++++++++++
 src/lib/start.s  |   9 ++
 src/lib/str.s    |  37 ++++++++
 src/lib/sys.s    |  50 +++++++++++
 src/lib/util.s   |  11 +++
 src/main.s       |  20 +++++
 src/test/heap.s  | 125 ++++++++++++++++++++++++++
 src/test/write.s |  55 ++++++++++++
 14 files changed, 711 insertions(+)
 create mode 100644 Makefile
 create mode 100755 build/main
 create mode 100644 build/test.txt
 create mode 100755 run
 create mode 100644 src/lib/format.s
 create mode 100644 src/lib/heap.s
 create mode 100644 src/lib/print.s
 create mode 100644 src/lib/start.s
 create mode 100644 src/lib/str.s
 create mode 100644 src/lib/sys.s
 create mode 100644 src/lib/util.s
 create mode 100644 src/main.s
 create mode 100644 src/test/heap.s
 create mode 100644 src/test/write.s

diff --git a/Makefile b/Makefile
new file mode 100644
index 0000000..1180811
--- /dev/null
+++ b/Makefile
@@ -0,0 +1,9 @@
+CC = riscv64-linux-gnu-gcc
+GCC_ARGS = -static -g -nostdlib
+SOURCES = $(wildcard src/*.s src/**/*.s)
+
+build/main: $(SOURCES)
+	$(CC) $(GCC_ARGS) -o build/main $(SOURCES)
+
+clean:
+	rm -r build/*
diff --git a/build/main b/build/main
new file mode 100755
index 0000000000000000000000000000000000000000..82aaee14c28e35c90bbad0e9e6097317dcbfdae0
GIT binary patch
literal 9624
zcmdT~eQ;FO6~FJj-54k&AuAu^2MY_Gmcb1q!J<VVkq~GRagr!?rapGxz9cJ~-R<rM
z2;)cGC008QDC>+>rxLN+${*GNEKbK6K!=$+V~chCqhsYmtQHuDggBkiTG*a*?>+n8
z-rYdye|<B#_q^ZzopaAU_w0T5-Iqt&)~?bujnSpEuNdAvWe9AAZ20ADA$Xx$!Im%&
zly$6@8H^=8fF-LWQK?od_tX>CXv?|WEsT9B8>xoQ_=PO&YE-t5P8E7o4{{b`RFfY1
zh<|?BjbDzL>bX*nYUJXD^|kN^<7DmYy4b<<$E$zy@}iF(-{gBa^8SWDy>G-m2~DXw
zHNyN0vKwb>T3dDysBAW1bN>F_GxN8PuwiZQc3+oAA7M;;btt=WPUM|PNXriH&0cTR
zG2Qo&Z~s`BX>C4Z(8$*?kG0a!^Iwgze9ka@HBT8<=ffbU_5FE^g?#xBTUnFc&(0pg
zp0Mv{>lw@KYyFY2UuQQOzI3h-cmwT?u#K}r&+Rwt6`^(3H}7hDhnl?aYT!j3Vu82z
zu>5B}7Fd{Of#wbtSZZGi90)TUMRpMF?#;fW|4Pq~Wed}9f(R@NuFNgl!E%dhw6UGm
zGk?}z-!X4^b1v6pu>4oKf_1S&H<ss^<vpf7zjIse^Mg&bX=Zs2vFCRNb4}h32L4nB
zmb}iecV7W}{!9xrzpFLv>{#*XI?Fm~G}V9~2aaj`YtL(ew~rO_iCMt9q~*YFp!t$E
zb@;_>ZW+i2PHMSjH5&4*>Juol{P~-JdqUfv3$y&`dXT|Zv%vyy8<%Dd&Gw3MiII)4
z!?mI3taGoh=~H23i@lAxc}EKgwxZS<eekipLtcpC;3NkV>{l9w+D1kT7ae?Lbk;@q
zyW}8(Idn5J&2I&cIWaQ2`$S%Ulm*_{1Ebi-rVSkd#`15n8!;mo11q1w-`^7KFs2-P
zwAFfIA2SRu#MNM4?~s1<(6piKU@i;D&vh1HU5I**9zsdvUcUMRZyI#9;e7R=fl_ub
zU(GxuZJaD5v_CTX$OUg(VzlsY%2*ijHQ@6FpO@()qlZo&te>L2kgcDxPtPl5U||<T
z82*-avD;T#>pUz3W7+))`}75Uv@lk`XIEfJ7klX1;|G1-K?5T8@saSwM!<CB&H8wR
zoq}wmUjy|oB4^LU838}eiR=#FU>wj{?trez_UlCZ?$758L7(SFMo*rp-Uxl1g=n6s
zj({deyZ<5B-f4n;=rrJ8<QhFJKlV;x&o1N5Y+>4V;C%sFr!C_dcIQFIBcJy4NYyD}
z;q!Xw&!;}`;cuRWtjWDOuijVXpPR2*F%vAD6_`E6coqF#em1+&r~RxBXXHAF^J+Vk
z^ru2`f1*F*PjvhH?7l>5VD?0ugNe+~YM{QOKb5lM8GkQuZ(~yc2`U#~h8Avx7F-VR
zO+_=&c#pq38nc1OCIFVP)0tpqYla(KZO38>|CU5577;zcx_P5q0D<ei3i5JeDEE2=
zf4i(7ll7Cbeo@x@W&O6SKalltS=0L5(hf#b(X_RhX}5#uO>MrVIog<9WcD>C7n&iI
zx*L;?W&{fhv29T+of1N~9k*;?FGSb)wE#+;OVzwwDc5!RxZs$(5d7}}B={R7zuQf6
z$%4PW$UiLk_f!re6a0Z9f0}%b;+$2w1pg&y68_M0cTy!XV1oZ%kv}Z$I}s^W6#NTC
z{zsCJ5vX(t{&g@q;SckOf$~JHpdk1yMgBy|uNP`%8iM~ok$;2Ck5y$%0pRo4%QWr`
zH%Su=&pgJy1ApI#KW&hB_^j5FP|(EoE`}S2HxKU69*$po7%b9+{#8d893mN9ip2S_
z4JgiJS4AGCh_(%OB{YLIc12zUc^?9gX0EZnA`cTr8?0iCW^8`0BJWA$)m;OnjQpgh
zOL#QkVdV7!k7j6>j!^l44<IoHYe{ix-YDT|Q&`>fDO!E4QFDFGyc&2+0RR6Gi-F%>
z$nqfiuW8@bOvVax4E{iv#g`S>_%I#hT73?-@PbXyDGR3?+60|xhL@L~2_BFIqH~1H
zAc4V&VD`%WVK$5Y7GZz9fc_|(jY(u*^itLr^o~AI??QGX=&f5<$P*lIp|zTGoUxEi
z$C^OOOI=1l)g=qiyNJebAtqN7joUC9yntvNmW!})3ysCY{r8OHxz{x><g<u_<0pCU
z#+~uf%nH6!3awIIwBU}X@U1-N<dqX`vgY;yWrL4Sl;pqTLn$J3v2^EvEB+PmQVWjd
zs<PRnkvg35blo_4;vUzPEl_+aGszS8NS(1)@rb!+fqW3w+@7fMcg>W@)wNgo%Wc72
z<pty_JvIy<<tlmNcq@8zk4PY5RiReF7v7>=&L3~Q<xF=@l0TQTEaF+}i8?Rky_6v$
zo}Cb%tNHD(!Fcil;z^HJTzQKgfCMY--mA2GH`?U|*rms@F|pDwhx&5njG~4}HP1HU
z6ul~0XNeE3A`1B6zM3f9i{A1AyroTnF&VSU>2Y$IC*{6fqjH2lS34^|MSpk!{?O)Q
zX3-mni<lMMo?m&KxGfUTy^@ulHY>&q`t^t$6eVRbj=$0hJri(ubVNRinJCRo5kWD#
zRa^^YH)p)n*UcgOZfnA(Q<5DADg9NIuSS<cXmr9F_UraXw2qHBmP?t!fA=U<nQS6H
z-iY|PL~i~1zshwd2l_C#cmcUZ`%q&h%_hye<A3SwJGdAZwK_N<7&kr^;b%H!HS~p|
z@nD)Y^d|c3hHz>i6mLk`$wayV-&$|p+|Zx4Q+O2UZ|U$i2Ah^JREkBz4c&=UUnm2r
z1mJtT>o%E+#@)^7Oej@)pK`I&18LV?e<m7}xA=zN;4;ncx4=<=4TQ^k4URE6Jn17V
zIxQ_0oh0Wn+$rvi;sm2kVX`iJ8L*@F%PpImXu#4y8|hNqU=jIVSc-cXog<Xuu)a)#
zhqQ7T{G?a`;nraIx>SA{^v<g^8T@2L0pZqwlbcGH!QZONTMRa-3`DOz>_S0p5X|!U
z)Lwy4FA8LD<~V$OEo9KI8VP*iK>TavJP2Qd5m%!u-rLLh_&SVyUb%{UxO|}?PZx?U
z_e*?65fMVK#8rMu;&i@GY7{qmMIih^E*Qo0EW(GlQ10hb5?A{jmUtbno#Hhv>TFCe
zjnMA_uQb0$INxA&u11!|xVpjUoQ-fA7i}jAe-DI8_K8p1CE|Z{1wL(qh=1}5eA<W*
z|J)V$v{4}bKgZ$YOE~_*=$w)G_!f;gojVd<D{(r9B%I<v8wtY2a-p+d$Ws%-XM>$e
z@m#>|Unr;vy;$~3=bmI|xy0!ll<+kYr*l!l$xnLN5sq~wf9?i58tkiPDC=Gi;P6d}
zy(Q22$WC11^A&uv#MQidkmDB$>Ur@Fj(b^B>GwrxXNHphuSxuj((msiu8#K)5?9x;
zCtx5rE;XO=YzlETua0s%<$nHU9Q?TKSA8CxmUv9@|4WH?D)`qDe^7be;r;^s9981u
z<9PXV?Z$EN1spFQ7w)j?ARp9uX_Eb_ztbfWA5;8aD)AEveuu=>b@fh(tLsLm#MR&3
z{St3g>@&-1TDzewW(5;$?pC;aV0}+hZwBrxYgN~M*47OmhGNm4xEbvWr8h~Li?Ab$
zm|RLnx7k7pqsY3$X55C4A$XJMHoL<l^@rK|mi9KYW6gbS47WaJBGD%VzAY1CcQlpG
znB6Jc7WZ~M!osOdW+G)KL-DAEPA|^<_|^gNEpBg#MdLO=J#7Q`S&O*m>ld}B`?|S!
z>$>QcXq1c1?XAf^9FJv%w=G_ChYcd%cbR?Z9u`St($L-3bS5QH^bff4A1vI|*aY15
zEuE{)J6kp|?kZQpPe5io)Cc`1;u-je#LV`!ceS>xHSb!rs-vyb>}+XW+h&4B%1RCh
zyYZN)nQ8XK65&wHOeSE5YNzG`(y_9ov&C#}YhSa@G{xvc@G;2}n?6yRxb>7fNE18;
zwbqUfvu)i<P%+JLI&F$z;-0fOmaS4sCqov@5Z^STwi!!oft@v<3@7B#cy|J9m3U*?
zkx(YY?5)uZP6taQ?RY37G^23<VU#gDE&%Q$k8UguAJozVeVI@g>P$-1y(GmGu!HW2
z_XorM(OBf>XoLkbm^;B#f_E1bWlsVj{D2h<WiqK~xF338!H6C1?=eI0g|ElC<<3)6
zIGnOK6OpHiYyk({FvLu3ZfNQLpX%#D3-@;LbK@87zx}X2;WbxO#nMxhguqY5L4*$w
z{GxSnrPRMkQBZDKGiV`|`ltPT1V0zR^|+{trK-<AyFe@d2o5#v`|1Ba)P175A8Q32
z?4R`M{h(S7NbD<tATQeIQQZzW=q9P1YWhEy)da{|hNX!91SA#1#>2AzQ%a-iKl-Oo
zP@N4+2X`rr$}P)`qu(fBS^mhaIfbg99Y_CPQvX`z)koFeA@vtJU2v&pssN5CIO$XU
z9JHgX>K~K(_|eRLk)FGz+;j6*PZM`5WE^YY_J{B%ZyDv)1i&bFgoY>|#}7hqbt}fH
XU(w3=*ZWHP=ly~q-WP~nKG**N+znmZ

literal 0
HcmV?d00001

diff --git a/build/test.txt b/build/test.txt
new file mode 100644
index 0000000000000000000000000000000000000000..4c5e6c44cd11b3ec3037aa620b33940720890019
GIT binary patch
literal 14
VcmeZB&B@7ED9<m-Nm1lt001S~1ZV&N

literal 0
HcmV?d00001

diff --git a/run b/run
new file mode 100755
index 0000000..8231ec4
--- /dev/null
+++ b/run
@@ -0,0 +1,13 @@
+#!/bin/sh
+make -s || exit
+cd build
+
+if [ "$1" = "d" ]; then
+    qemu-riscv64 -g 1234 main &
+    riscv64-linux-gnu-gdb -q \
+        -ex "target remote :1234" \
+        main
+else
+    qemu-riscv64 main
+fi
+
diff --git a/src/lib/format.s b/src/lib/format.s
new file mode 100644
index 0000000..c975b6e
--- /dev/null
+++ b/src/lib/format.s
@@ -0,0 +1,62 @@
+.align 2
+.section .text
+
+
+
+# args:
+# a0 - number
+#
+# returns:
+# a0,a1 - hex string
+.global format_hex
+format_hex:
+    addi    sp, sp, -(3*8)
+    sd      ra, 0(sp)
+    sd      s0, 8(sp)
+    sd      s1, 16(sp)
+
+    move    s0, a0
+    jal     format_hex_lower
+    move    s1, a0
+
+    srli    a0, s0, 32
+    jal     format_hex_lower
+
+    move    a1, s1
+
+    ld      ra, 0(sp)
+    ld      s0, 8(sp)
+    ld      s1, 16(sp)
+    addi    sp, sp, +(3*8)
+    ret
+
+# args:
+# a0 - number
+#
+# returns:
+# a0 - lower hex string
+.global format_hex_lower
+format_hex_lower:
+    move    t0, a0
+    li      t1, 0xffffffff
+    and     t0, t0, t1
+    li      a0, 0
+    li      t1, 8*7
+    li      t4, 16*4
+0:
+    bltz    t1, 0f
+
+    andi    t2, t0, 0xf
+    addi    t2, t2, 0x30
+    li      t3, 0x30+9
+    ble     t2, t3, 1f
+    addi    t2, t2, 0x61-0x30-10
+1:
+    sll     t2, t2, t1
+    addi    t1, t1, -8
+    srli    t0, t0, 4
+    or      a0, a0, t2
+    j       0b
+0:
+    ret
+
diff --git a/src/lib/heap.s b/src/lib/heap.s
new file mode 100644
index 0000000..8ae1e5c
--- /dev/null
+++ b/src/lib/heap.s
@@ -0,0 +1,225 @@
+# This is a heap implemented with brk.
+# It's slow / unoptimized, and only for
+# learning how to set up a basic heap
+
+# mask and imask are used to floor & ceil
+# to get correct bounds
+.equ align_imask,   0b111
+.equ align_mask,    ~align_imask
+
+.equ used_mask,     0b001
+.equ size_mask,     align_mask
+
+# block node
+
+.equ bsize, 0
+.equ fb_next, 8     # free only
+# free also contains its address at the end
+
+# sizes of metadata
+
+.equ sizeof_fb, (8*3 + align_imask) & align_mask
+.equ sizeof_ub, (8*1 + align_imask) & align_mask
+
+.equ PAGE_SIZE, 4096
+
+
+
+.align 2
+.section .rodata
+
+.word 0f - heap_oom
+heap_oom:
+    .string "Heap ran out of memory!\n"
+0:
+
+.section .data
+
+.align 4
+.equ heap_start, 0
+.equ heap_first_free, 8 # matches fb_next
+.equ heap_end, 16
+.global heap_info       # for testing only
+heap_info:
+    .dword __global_pointer$
+    .dword 0
+    .dword 0
+
+
+
+.align 2
+.section .text
+
+.global heap_init
+heap_init:
+    addi    sp, sp, -8
+    sd      ra, 0(sp)
+
+    # get heap info (t0)
+
+    la      t0, heap_info
+
+    # set heap start (t1)
+
+    ld      t1, heap_start(t0)
+    addi    t1, t1, align_imask
+    andi    t1, t1, align_mask
+    sd      t1, heap_start(t0)
+
+    # set heap end (a0)
+    # also calculate heap size (t2)
+
+    li      a0, 0
+    jal     brk
+    andi    a0, a0, align_mask
+    sub     t2, a0, t1      # size = end - start (t2)
+    li      t3, sizeof_fb
+    bgeu    t2, t3, 0f      # check if enough mem to start
+
+    move    a1, a0
+    add     a0, t1, t3
+    jal     brk_or_panic    # if not, get more
+    sub     t2, a0, t1      # recalc size (t2)
+0:
+    sd      a0, heap_end(t0)
+
+    # create initial free block
+
+    ori     t2, t2, 0x1     # add prev used
+    sd      t2, bsize(t1)   # store size
+    sd      t0, fb_next(t1) # store next
+    sd      t1, -8(a0)      # store addr at end
+
+    sd      t1, heap_first_free(t0)
+
+    ld      ra, 0(sp)
+    addi    sp, sp, +8
+    ret
+
+# args:
+# a0 - size
+#
+# returns:
+# a0 - address
+.global heap_alloc
+heap_alloc:
+    addi    sp, sp, -8
+    sd      ra, 0(sp)
+
+    # align size properly (t0)
+
+    move    t0, a0
+    addi    t0, t0, sizeof_ub
+    addi    t0, t0, align_imask
+    andi    t0, t0, align_mask
+
+    # get a free block that will fit (t1)
+    # and its free space
+
+    la      t3, heap_info
+    ld      t4, heap_first_free(t3)
+    ld      a1, heap_end(t3)
+
+    move    t6, t3              # prev block (t6)
+
+    bne     t4, t3, 0f          # if no free blocks
+    move    t4, a1              # pretend end is start
+    j       3f
+0:
+
+    move    t1, t4              # current block (t1)
+
+0:
+    ld      t2, bsize(t1)       # size of current block (t2)
+    andi    t2, t2, size_mask
+    bgeu    t2, t0, 0f          # is it big enough
+    ld      t5, fb_next(t1)     # if not, get the next
+    beq     t5, t3, 1f
+    move    t6, t1
+    move    t1, t5
+    j       0b
+1:  # if no blocks are big enough
+    add     t5, t1, t2          # get end of last free block
+    beq     t5, a1, 2f          # if no free block at end of heap:
+    move    t6, t1
+3:
+    move    t1, a1              # immitate new free block at end
+2:
+    add     a0, t1, t0          # get needed heap end (a0)
+    jal     brk_or_panic        # set heap end (a0)
+    sd      a0, heap_end(t3)    # update end in info
+    sub     t2, a0, t1          # new free space (t2)
+    andi    t5, t2, 1           # prev used bit
+    sd      t5, bsize(t1)       # update size
+    sd      t3, fb_next(t1)     # update next (for case 3)
+
+0:
+
+    # deal with extra free space
+
+    sub     t5, t2, t0          # unneeded free space (t5)
+    li      t4, sizeof_fb
+    bltu    t5, t4, 0f          # check if enough for a free block
+
+    add     t3, t1, t0          # if so, get addr (t3)
+    sd      t3, fb_next(t6)     # set prev block next to new
+    add     t6, t3, t5          # store addr at end
+    sd      t3, -8(t6)
+    ori     t6, t5, 1           # store size with prev in use
+    sd      t6, bsize(t3)
+    ld      t6, fb_next(t1)     # copy next
+    sd      t6, fb_next(t3)
+    j       1f
+0:
+    move    t0, t2              # if no space, fill in with used
+    ld      t4, fb_next(t1)
+    sd      t4, fb_next(t6)     # set prev next to cur next
+    ld      t4, heap_end(t3)
+    add     t3, t1, t0
+    beq     t3, t4, 1f          # if this is not at the end
+    ld      t4, bsize(t3)       # set next's prev used to 1
+    ori     t4, t4, 1
+    sd      t4, bsize(t3)
+1:
+
+    # create used block
+
+    add     t2, t0, t1          # end of block
+    ori     t0, t0, 1           # prev used bit
+    sd      t0, bsize(t1)       # store size
+    sd      zero, fb_next(t1)   # remove free block stuff
+    sd      zero, -8(t2)
+
+    move    a0, t1
+    addi    a0, a0, sizeof_ub
+
+    ld      ra, 0(sp)
+    addi    sp, sp, +8
+    ret
+
+# args:
+# a0 - address
+.global heap_free
+heap_free:
+    ret
+
+# args:
+# a0 - min address needed
+# a1 - old address
+#
+# returns:
+# a0 - new address, aligned
+brk_or_panic:
+    addi    sp, sp, -8
+    sd      ra, 0(sp)
+
+    jal     brk
+    andi    a0, a0, align_mask
+    bgtu    a0, a1, 0f      # make sure brk worked
+    la      a0, heap_oom    # if not, panic
+    lw      a1, -4(a0)
+    j       panic
+0:
+    ld      ra, 0(sp)
+    addi    sp, sp, +8
+    ret
diff --git a/src/lib/print.s b/src/lib/print.s
new file mode 100644
index 0000000..888c158
--- /dev/null
+++ b/src/lib/print.s
@@ -0,0 +1,95 @@
+.section .rodata
+
+newline:
+    .half '\n'
+space:
+    .half ' '
+
+
+
+.align 2
+.section .text
+
+# only uses a regs for convenience
+#
+# args:
+# a0 - string
+# a1 - length
+.global print
+print:
+    addi    sp, sp, -8
+    sd      ra, (sp)
+
+    move    a2, a1
+    move    a1, a0
+    li      a0, 1 # stdout
+    jal write
+
+    ld      ra, (sp)
+    addi    sp, sp, +8
+    ret
+
+# only uses a regs for convenience
+.global printnl
+printnl:
+    addi    sp, sp, -8
+    sd      ra, (sp)
+
+    la      a0, newline
+    li      a1, 1
+    jal     print
+
+    ld      ra, (sp)
+    addi    sp, sp, +8
+    ret
+
+# only uses a regs for convenience
+#
+# args:
+# a0 - string
+# a1 - length
+.global println
+println:
+    addi    sp, sp, -8
+    sd      ra, (sp)
+
+    jal     print
+    jal     printnl
+
+    ld      ra, (sp)
+    addi    sp, sp, +8
+    ret
+
+.global print_space
+print_space:
+    addi    sp, sp, -8
+    sd      ra, (sp)
+
+    la      a0, space
+    li      a1, 1
+    jal     print
+
+    ld      ra, (sp)
+    addi    sp, sp, +8
+    ret
+
+# args:
+# a0 - the hex value to print
+.global print_hex
+print_hex:
+    addi    sp, sp, -(8+16)
+    sd      ra, (sp)
+
+    jal     format_hex
+    addi    t0, sp, 8
+    sd      a0, 0(t0)
+    sd      a1, 8(t0)
+
+    move    a0, t0
+    li      a1, 16
+    jal     print
+
+    ld      ra, (sp)
+    addi    sp, sp, +(8+16)
+    ret
+
diff --git a/src/lib/start.s b/src/lib/start.s
new file mode 100644
index 0000000..11e61b1
--- /dev/null
+++ b/src/lib/start.s
@@ -0,0 +1,9 @@
+.align 2
+.section .text
+
+.global _start
+_start:
+    jal     heap_init
+    jal     main
+    j       exit
+
diff --git a/src/lib/str.s b/src/lib/str.s
new file mode 100644
index 0000000..b412e10
--- /dev/null
+++ b/src/lib/str.s
@@ -0,0 +1,37 @@
+.align 2
+.section .text
+
+# args:
+# a0 - string
+#
+# returns:
+# a0 - length
+.global strlen
+strlen:
+    li      t0, 0
+0:
+    beq     t0, a1, 0f
+    lb      t1, (a0)
+    beqz    t1, 0f
+    addi    a0, a0, 1
+    addi    t0, t0, 1
+    j       0b
+0:
+    move    a0, t0
+    ret
+
+# args:
+# a0 - dest
+# a1 - src
+.global strcpy
+strcpy:
+0:
+    lb      t0, (a1)
+    beqz    t0, 0f
+    sb      t0, (a0)
+    addi    a0, a0, 1
+    addi    a1, a1, 1
+    j       0b
+0:
+    sb      t0, (a0)
+    ret
diff --git a/src/lib/sys.s b/src/lib/sys.s
new file mode 100644
index 0000000..b8b5bd5
--- /dev/null
+++ b/src/lib/sys.s
@@ -0,0 +1,50 @@
+# This contains all syscalls used,
+# as functions for convenience.
+# These are guaranteed to not modify
+# any registers other than the
+# arguments needed for the syscalls
+
+.align 2
+.section .text
+
+# args:
+# a0 - code
+.global exit
+exit:
+    li      a7, 93
+    ecall
+0: j 0b # loop if failed for safety
+
+# args:
+# a0 - relative dir fd;
+#      0 for none, -100 for cwd
+# a1 - path / name
+# a2 - flags
+# a3 - mode
+#
+# returns:
+# a0 - fd
+.global openat
+openat:
+    li      a7, 56
+    ecall
+    ret
+
+# args:
+# a0 - fd
+# a1 - content buf
+# a2 - size
+.global write
+write:
+    li      a7, 64
+    ecall
+    ret
+
+# args:
+# a0 - address to end at
+#      returns current addr if 0
+.global brk
+brk:
+    li      a7, 214
+    ecall
+    ret
diff --git a/src/lib/util.s b/src/lib/util.s
new file mode 100644
index 0000000..f111e7a
--- /dev/null
+++ b/src/lib/util.s
@@ -0,0 +1,11 @@
+.align 2
+.section .text
+
+# args:
+# a0 - message
+# a1 - length
+.global panic
+panic:
+    jal     print
+    li      a0, 1
+    j       exit
diff --git a/src/main.s b/src/main.s
new file mode 100644
index 0000000..5680c92
--- /dev/null
+++ b/src/main.s
@@ -0,0 +1,20 @@
+.align 2
+.section .text
+
+.global main
+main:
+    addi    sp, sp, -8
+    sd      ra, 0(sp)
+
+    # do stuff
+
+    #jal     write_test
+    jal     heap_test
+
+    # exit with code 0
+
+    ld      ra, 0(sp)
+    addi    sp, sp, +8
+
+    li      a0, 0
+    ret
diff --git a/src/test/heap.s b/src/test/heap.s
new file mode 100644
index 0000000..3b4ccc8
--- /dev/null
+++ b/src/test/heap.s
@@ -0,0 +1,125 @@
+.section .rodata
+
+.word 0f - print_msg
+print_msg:
+    .string "Current heap:"
+0:
+
+.word 0f - dots
+dots:
+    .string "................"
+0:
+
+.word 0f - hexstr
+hexstr:
+    .string "0x"
+0:
+
+
+
+.align 2
+.section .text
+
+.global heap_test
+heap_test:
+    addi    sp, sp, -(3*8)
+    sd      ra, 0(sp)
+    sd      s0, 8(sp)
+    sd      s1, 16(sp)
+
+    # empty heap
+
+    jal     print_heap
+    jal     printnl
+
+    # put stuff on heap
+
+    li      a0, 8*4
+    jal     heap_alloc
+    li      t0, 0x1111111111111111
+    sd      t0, (a0)
+    sd      t0, 8(a0)
+    sd      t0, 24(a0)
+
+    li      s0, 0x0f
+0:
+    bltz    s0, 0f
+
+    li      a0, 8*3
+    jal     heap_alloc
+    sd      s0, (a0)
+    li      t0, 0xf000000000000000
+    add     t0, s0, t0
+    sd      t0, 16(a0)
+
+    addi    s0, s0, -1
+    j       0b
+0:
+
+    li      a0, 8*7
+    jal     heap_alloc
+    li      t0, 0xffff
+    sd      t0, 6*8(a0)
+
+    li      a0, 8*3
+    jal     heap_alloc
+
+    jal     print_heap
+
+    ld      ra, 0(sp)
+    ld      s0, 8(sp)
+    ld      s1, 16(sp)
+    addi    sp, sp, +(3*8)
+    ret
+
+print_heap:
+    addi    sp, sp, -(3*8)
+    sd      ra, 0(sp)
+    sd      s0, 8(sp)
+    sd      s1, 16(sp)
+
+    la      a0, print_msg
+    lw      a1, -4(a0)
+    jal     println
+
+    la      t0, heap_info
+    ld      s0, 0(t0)
+    ld      s1, 16(t0)
+0:
+    la      a0, hexstr
+    lw      a1, -4(a0)
+    jal     print
+    move    a0, s0
+    jal     print_hex
+    jal     print_space
+
+    ld      a0, 0(s0)
+    jal     print_hex
+    jal     print_space
+
+    ld      a0, 8(s0)
+    jal     print_hex
+    jal     print_space
+
+    la      a0, dots
+    lw      a1, -4(a0)
+    jal     print
+    jal     print_space
+
+    ld      t0, 0(s0)
+    andi    t0, t0, ~0b11
+    add     t0, s0, t0
+    ld      a0, -8(t0)
+    move    s0, t0
+    jal     print_hex
+    jal     printnl
+
+    beq     s0, s1, 0f
+    j 0b
+0:
+
+    ld      ra, 0(sp)
+    ld      s0, 8(sp)
+    ld      s1, 16(sp)
+    addi    sp, sp, +(3*8)
+    ret
diff --git a/src/test/write.s b/src/test/write.s
new file mode 100644
index 0000000..5a13b07
--- /dev/null
+++ b/src/test/write.s
@@ -0,0 +1,55 @@
+.equ PATH_MAX,  255
+
+.section .rodata
+
+    .word 0f - start_msg
+start_msg:
+    .string "Writing file..."
+0:
+
+    .word 0f - file_name
+file_name:
+    .string "test.txt"
+0:
+
+    .word 0f - content
+content:
+    .string "Hello world!\n"
+0:
+
+
+
+.align 2
+.section .text
+
+.global write_test
+write_test:
+    addi    sp, sp, -8-PATH_MAX
+    sd      ra, 0(sp)
+
+    # print msg
+
+    la      a0, start_msg
+    lw      a1, -4(a0)
+    jal     println
+
+    # open file
+
+    li      a0, -100
+    la      a1, file_name
+    li      a2, 01102       # TRUNC | CREAT | RDWR
+    li      a3, 0b110100100 # -rw-r--r--
+    jal     openat
+
+    # write to file
+
+    la      a1, content
+    lw      a2, -4(a1)
+    jal     write
+
+    # return
+
+    ld      ra, 0(sp)
+    addi    sp, sp, +8+PATH_MAX
+
+    ret